forked from TCShenanigans/symphony_stdlib
114 lines
2.4 KiB
NASM
114 lines
2.4 KiB
NASM
; Multiplies r1 and r2, returning the lower part of the result
|
|
; Arguments:
|
|
; r1 - The first value
|
|
; r2 - The second value
|
|
; Result:
|
|
; r1 - The lower 32 bits of the result
|
|
; Clobbers: r2, r3, r4, r5, r6
|
|
pub mul_low:
|
|
cmp r1, r2
|
|
jbe mul_low_noswap
|
|
xor r1, r2, r1
|
|
xor r2, r1, r2
|
|
xor r1, r2, r1
|
|
; Passthrough
|
|
|
|
; Multiplies r1 and r2, returning the lower part of the result
|
|
; This method assumes r1 is smaller than r2, which results in faster execution
|
|
; Arguments:
|
|
; r1 - The first value
|
|
; r2 - The second value
|
|
; Result:
|
|
; r1 - The lower 32 bits of the result
|
|
; Clobbers: r2, r3, r4, r5, r6
|
|
pub mul_low_noswap:
|
|
mov r4, 0 ; r4 has the result
|
|
mov r6, mul_loop_end
|
|
add r3, r2, r2
|
|
|
|
mul_loop:
|
|
and r5, r1, 14 ; Taking the first four bits, discarding the odd
|
|
lsl r5, r5, 1 ; 0000 - 0, 0001 - 2, 0010 - 4, 0011 - 8, etc.
|
|
sub r5, r6, r5
|
|
jmp r5
|
|
|
|
add r4, r4, r3
|
|
add r4, r4, r3
|
|
add r4, r4, r3
|
|
add r4, r4, r3
|
|
add r4, r4, r3
|
|
add r4, r4, r3
|
|
add r4, r4, r3
|
|
mul_loop_end:
|
|
mov flags, r1
|
|
jne mul_skip_one
|
|
add r4, r4, r2
|
|
mul_skip_one:
|
|
lsl r2, r2, 4
|
|
lsl r3, r3, 4
|
|
lsr r1, r1, 4
|
|
cmp r1, zr
|
|
jne mul_loop
|
|
|
|
mov r1, r4
|
|
jmp r13
|
|
|
|
; Calculates the absolute value of the value provided in the r1 register
|
|
; Arguments:
|
|
; r1 - The value for which we want the absolute value
|
|
; Result:
|
|
; r1 - The calculated absolute value
|
|
; Clobbers: r2
|
|
; Info: Based on Stanford's BitHacks
|
|
pub abs: ; SHOULD BE INLINED
|
|
; mask = v >> 31
|
|
asr r2, r1, 31
|
|
; v + mask
|
|
add r1, r1, r2
|
|
; return (v + mask) ^ mask
|
|
xor r1, r1, r2
|
|
jmp r13
|
|
|
|
; Calculates the minimum value of the two values provided in the r1 and r2 registers
|
|
; Arguments:
|
|
; r1 - The first value
|
|
; r2 - The second value
|
|
; Result:
|
|
; r1 - The smaller value
|
|
; Clobbers: Nothing
|
|
; Info: Based on Stanford's BitHacks
|
|
pub min: ; SHOULD BE INLINED
|
|
; x < y
|
|
cmp r1, r2
|
|
lsr flags, flags, 2
|
|
; -(x < y)
|
|
neg flags, flags
|
|
; x ^ y
|
|
xor r1, r1, r2
|
|
; (x ^ y) & -(x < y)
|
|
and r1, r1, flags
|
|
; return y ^ ((x ^ y) & -(x < y))
|
|
xor r1, r2, r1
|
|
jmp r13
|
|
|
|
; Calculates the maximum value of the two values provided in the r1 and r2 registers
|
|
; Arguments:
|
|
; r1 - The first value
|
|
; r2 - The second value
|
|
; Result:
|
|
; r1 - The smaller value
|
|
; Clobbers: r2
|
|
; Info: Based on Stanford's BitHacks
|
|
pub max: ; SHOULD BE INLINED
|
|
; x < y
|
|
cmp r1, r2
|
|
lsr flags, flags, 2
|
|
; -(x < y)
|
|
neg flags, flags
|
|
; x ^ y
|
|
xor r2, r1, r2
|
|
; (x ^ y) & -(x < y)
|
|
and r2, r2, flags
|
|
; return x ^ ((x ^ y) & -(x < y))
|
|
xor r1, r1, r2
|
|
jmp r13 |